Example Code for Arduino-Read Measured Distance

Hardware Preparation

• 1 x Arduino Leonardo (Since RS485 to TTL will occupy one serial port, it is recommended using a device with two or more serial ports like Arduino Leonardo. Arduino Modbus protocol takes up a lot of memory, so we recommend to use Arduino mega2560 board.)
• 1 x RS485 Shield for Arduino
• 1 x DC Power Supply (DC 24V)
• 1 x USB Cable (Connect Arduino board and a PC)

Software Preparation

• Arduino IDE
• Open "Library Manager"(Ctrl+Shift+I) in IDE, find and install ArduinoModbus and ArduinoRS485 libraries.
  

Wiring Diagram

Other Preparation Work

Install ArduinoModbus and ArduinoRS485 libraries via Arduino IDE's Library Manager.

Sample Code

/**************************************************************************************************************
*This code tests the range finder function of the URM12 ultrasonic sensor(1500cm&RS485)
*@ author : [email protected]
*@ data   : 30.09.2019
*@ version: 1.0
**************************************************************************************************************/
#include <ArduinoModbus.h>
#include <ArduinoRS485.h>

#define slave_addr   0x0b

#define TEMP_CONFIG_BIT       (0x03)
#define MEASURE_MODE_BIT      (0x01 << 2)
#define MEASURE_TRIG_BIT      (0x01 << 3)

typedef enum
{
  PID,
  VID,
  SLAVE_ADDR,
  COM_BAUDRATE,
  COM_PARITY_STOP,
  DISTANCE,
  INTERNAL_TEMP,
  EXTERN_TEMP,
  CR
} regindex;

volatile uint16_t cr_t = 0;

uint16_t read_data(uint16_t addr_t, uint16_t reg)
{
  uint16_t data_t;
  if (!ModbusRTUClient.requestFrom(addr_t, HOLDING_REGISTERS, reg, 1))
  {
    Serial.print("failed to read registers! ");
    Serial.println(ModbusRTUClient.lastError());
    data_t = 0xffff;
  }
  else
  {
    data_t =  ModbusRTUClient.read();
  }
  return data_t;
}


uint16_t write_data(uint16_t addr_t, uint16_t reg, uint16_t data)
{

  if (!ModbusRTUClient.holdingRegisterWrite(addr_t, reg, data))
  {
    Serial.print("Failed to write coil! ");
    Serial.println(ModbusRTUClient.lastError());
    return 0;
  }
  else
    return 1;
}

void setup() {
  ModbusRTUClient.begin(19200);
  Serial.begin(9600);
  cr_t |= MEASURE_MODE_BIT;// Set bit2
  cr_t &= ~(uint16_t)TEMP_CONFIG_BIT;//internal temp compensation
  write_data(slave_addr, CR, cr_t); //write CR
  delay(100);
}
volatile  uint16_t dist_t;
void loop() {
  cr_t |= MEASURE_TRIG_BIT;//Set bit3
  write_data(slave_addr, CR, cr_t); //write CR
  delay(300);// delay 300ms
  dist_t = read_data(slave_addr,DISTANCE);

  Serial.print("distance = ");
  Serial.print(dist_t, 1);
  Serial.println("cm");
}

Result