Example Code for Arduino-Blue Green Algae and Temperature Monitoring

Hardware Preparation

• DFRduino UNO R3 (or similar) x 1
• Gravity: Active Isolated RS485 to UART Signal Adapter Module x 1
• RS485 Water Quality Blue Green Algae Sensor x 1

Software Preparation

• Arduino IDE

Wiring Diagram

If the power of the RS485 device is small and the required current is less than 12V-160mA, the RS485 to UART signal conversion module does not require a 12V external power supply, making wiring more convenient.

Other Preparation Work

• Confirm the sensor's default device address (0x01) and baud rate (4800bit/s) match the settings in the sample code
• Ensure RS485 A/B lines are connected correctly (A to A, B to B) between the adapter module and the sensor
• Remove the black rubber protective cover from the sensor before measurement
• The sensor is factory-calibrated and ready to use; no initial calibration is required
• This sample code is compatible with UNO R3, Mega2560, and ESP32 development boards.

Sample Code

// ---------------- Cross-Platform Serial Configuration ----------------
#if defined(__AVR_ATmega2560__)
// Arduino Mega 2560: Use hardware serial port Serial1
// Sensor TX connects to Mega Pin 18
// Sensor RX connects to Mega Pin 19
#define sensorSerial Serial1

#elif defined(ESP32)
// ESP32: Manually instantiate hardware serial port; compatible with all models including C3/S2/S3/WROOM, etc.
#include <HardwareSerial.h>
HardwareSerial mySensorSerial(1); // Consistently use internal UART 1
#define sensorSerial mySensorSerial

#else
// Arduino UNO: Software serial port
// Sensor TX connects to UNO Pin 3
// Sensor RX connects to UNO Pin 2
#include <SoftwareSerial.h>
SoftwareSerial mySerial(2, 3);
#define sensorSerial mySerial
#endif
// ------------------------------------------------

uint8_t Com[8] = { 0x01, 0x03, 0x00, 0x00, 0x00, 0x03, 0x05, 0xCb };

void setup() {
Serial.begin(115200);

// Print a line of plain English text for testing. If this line appears clearly and without garbled characters,
// it indicates that communication between the computer and the development board is fully functional! Serial.println("");
Serial.println("--- System Start ---");

// Initialize the sensor serial port for different development boards
// (The sensor's baud rate must remain at 4800—do not change it)
#if defined(ESP32)
// ESP32 specific pins: RX connected to 16, TX connected to 17;
// pins can be customized based on the specific board model
sensorSerial.begin(4800, SERIAL_8N1, 16, 17);
#else
// UNO and Mega 2560
sensorSerial.begin(4800);
#endif
}

void loop() {
  Cyanobacteria_TEM();
  delay(1000);
}

void Cyanobacteria_TEM(void) {
  float tem;
  uint32_t val = 0;
  uint8_t Data[12] = { 0 };
  uint8_t ch = 0;
  bool flag = 1;
  long timeStart = millis();
  long timeStart1 = 0;
  while (flag) {

    if ((millis() - timeStart1) > 100) {
      while (sensorSerial.available() > 0) {
        sensorSerial.read();
      }
      sensorSerial.write(Com, 8);
      timeStart1 = millis();
    }

    if ((millis() - timeStart) > 1000) {
      Serial.println("Time out");
      return;
    }

    if (readN(&ch, 1) == 1) {
      if (ch == 0x01) {
        Data[0] = ch;
        if (readN(&ch, 1) == 1) {
          if (ch == 0x03) {
            Data[1] = ch;
            if (readN(&ch, 1) == 1) {
              if (ch == 0x06) {
                Data[2] = ch;
                if (readN(&Data[3], 8) == 8) {
                  if (CRC16_2(Data, 9) == (Data[9] * 256 + Data[10])) {
                    val = Data[3];
                    val = (val << 8) | Data[4];
                    val = (val << 8) | Data[5];
                    val = (val << 8) | Data[6];
                    float *chi = (float *)&val;
                    Serial.print("Cyanobacteria = ");
                    Serial.print(*chi);
                    Serial.print(" cells/ml ");
                    tem = (Data[7] * 256 + Data[8]) / 10.0;
                    Serial.print(" Temperature = ");
                    Serial.print(tem, 1);
                    Serial.println("°C ");
                    flag = 0;
                  }
                }
              }
            }
          }
        }
      }
    }
  }
}

uint8_t readN(uint8_t *buf, size_t len) {
  size_t offset = 0, left = len;
  int16_t Tineout = 500;
  uint8_t *buffer = buf;
  long curr = millis();
  while (left) {
    if (sensorSerial.available()) {
      buffer[offset] = sensorSerial.read();
      offset++;
      left--;
    }
    if (millis() - curr > Tineout) {
      break;
    }
  }
  return offset;
}

unsigned int CRC16_2(unsigned char *buf, int len) {
  unsigned int crc = 0xFFFF;
  for (int pos = 0; pos < len; pos++) {
    crc ^= (unsigned int)buf[pos];
    for (int i = 8; i != 0; i--) {
      if ((crc & 0x0001) != 0) {
        crc >>= 1;
        crc ^= 0xA001;
      } else {
        crc >>= 1;
      }
    }
  }

  crc = ((crc & 0x00ff) << 8) | ((crc & 0xff00) >> 8);
  return crc;
}

Result

Serial monitor baud rate selection: 115200，The displays the Blue Green Algae value, temperature data collected by the sensor.

Additional Information

• The sensor includes automatic temperature compensation to ensure accurate readings under varying environmental conditions.
• The sensor's IP68 waterproof rating allows it to be submerged in water for extended periods, suitable for various aquatic monitoring applications.